Notepad Online

Adicione uma senha para proteger dados sensíveis ou o bloco de notas será excluído.

@echo off
setlocal enabledelayedexpansion

:: =====================================
:: CONFIGURAÇÕES FIREBIRD
:: =====================================
set FIREBIRD_PATH=C:\Program Files (x86)\Firebird\Firebird_4_0
set ISC_USER=SYSDBA
set ISC_PASSWORD=masterkey
set FIREBIRD_HOST=127.0.0.1/3056:C:\AntecipePro\DADOS.FDB
set BACKUP_DIR=C:\AntecipePro\backup

:: =====================================
:: CONFIGURAÇÕES MINIO (SEPARADO)
:: =====================================
set MINIO_ENDPOINT=https://n8n-minio.7zmcaa.easypanel.host
set BUCKET_NAME=backup
set CNPJ_CLIENTE=14406482000199
set ACCESS_KEY=leDxH2eJIYFQGzFv1Dgf
set SECRET_KEY=ex5ev7zwxktKNWk0TZ4SxRfNiAS5knHJh0JEZpkC
set HOST_HEADER=n8n-minio.7zmcaa.easypanel.host

:: =====================================
:: PROGRAMAS
:: =====================================
set "CURL_EXE=C:\AntecipePro\Backup\curl.exe"
set "ZIP_EXE=C:\Program Files (x86)\7-Zip\7z.exe"

:: =====================================
:: VALIDAR PROGRAMAS
:: =====================================
if not exist "%CURL_EXE%" exit /b 10
if not exist "%ZIP_EXE%" exit /b 11

:: =====================================
:: CRIAR PASTA BACKUP
:: =====================================
if not exist "%BACKUP_DIR%" mkdir "%BACKUP_DIR%"

:: =====================================
:: NOME FIXO (SOBRESCREVE)
:: =====================================
set DIA=%DATE:~0,2%

set BACKUP_FILE=bkp_dados_%DIA%.fbk
set COMPRESSED_FILE=bkp_dados_%DIA%.fbk.7z

set FULL_BACKUP_PATH=%BACKUP_DIR%\%BACKUP_FILE%
set FULL_COMPRESSED_PATH=%BACKUP_DIR%\%COMPRESSED_FILE%

:: =====================================
:: BACKUP FIREBIRD
:: =====================================
cd /d "%FIREBIRD_PATH%"

gbak -b -g -user %ISC_USER% -password %ISC_PASSWORD% %FIREBIRD_HOST% "%FULL_BACKUP_PATH%"

if %ERRORLEVEL% neq 0 exit /b 1

:: =====================================
:: COMPACTAR
:: =====================================
set ZIP_PASSWORD=suporte123@

"%ZIP_EXE%" a -t7z "%FULL_COMPRESSED_PATH%" "%FULL_BACKUP_PATH%" -mx=9 -mhe=on -p%ZIP_PASSWORD%

if %ERRORLEVEL% neq 0 exit /b 2

set ZIP_PASSWORD=

del "%FULL_BACKUP_PATH%"

:: =====================================
:: UPLOAD MINIO (URL CORRIGIDA)
:: =====================================
"%CURL_EXE%" --http1.1 ^
 --fail ^
 --connect-timeout 60 ^
 --max-time 0 ^
 --upload-file "%FULL_COMPRESSED_PATH%" ^
 --insecure ^
 -H "Host: %HOST_HEADER%" ^
 -H "Content-Type: application/octet-stream" ^
 -H "x-amz-content-sha256: UNSIGNED-PAYLOAD" ^
 --aws-sigv4 "aws:amz:us-east-1:s3" ^
 --user "%ACCESS_KEY%:%SECRET_KEY%" ^
 "%MINIO_ENDPOINT%/%BUCKET_NAME%/%CNPJ_CLIENTE%/%COMPRESSED_FILE%"

if %ERRORLEVEL% neq 0 (
    echo [%DATE% %TIME%] Erro no upload cURL. Codigo: %ERRORLEVEL% >> "%BACKUP_DIR%\erro_minio.log"
    exit /b 3
)

exit /b 0